User:Amadalvarez/Queries
SINTAXI COMUNES
- Per forçar format sortida
#defaultView:Timeline
#defaultView:Map
....
- Title
#title: Aquest és el titol
- Eliminar accents. Habitualment, per poder ordenar
ORDER BY (REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(LCASE(?text),"[àá]","a"),"[èé]","e"),"[ìíï]","i"),"[òó]","o"),"[ùúü]","u"),"[ç]","c"),"[ñ]","n"))
Sintaxi selecció
[edit]- Seleccionar items amb articles en català (mostra enllaç a l'article)
?sitelink schema:about ?item;
schema:inLanguage "ca".
- Seleccionar items amb articles en català (mostra nom de l'article)
?sitelink schema:about ?item;
schema:inLanguage "ca"
;
schema:name ?article .
- Seleccionar items amb label en català
?item rdfs:label ?itemLabel.
FILTER((LANG(?itemLabel)) = "ca")
- Seleccionar items amb descripció en català
?item schema:description ?itemDescription.
FILTER((LANG(?itemDescription)) = "ca")
- seleccionar tots els ranks
?item wdt:P31 wd:Q33146843(o ?variable).
?item p:P31 [ps:P31 wd:Q33146843(o ?variable)]
seleccionar rank preferred:
?item p:P31 [ps:P31 ?poblacio; pq:P585 ?pointInTime; wikibase:rank wikibase:PreferredRank] .
- filtrar per desigual
FILTER( ?value != wd:Q184377 )
Enllaços curts de casos específics
[edit]- https://w.wiki/427q Llista de propietat P856 (web) amb arxiu P1065
- https://w.wiki/45xW Persones amb més d'una P1026 (tesi)
- https://w.wiki/48PZ Llista (amb values) d'esports amb > 5000 crides per mostrar propietats diverses
- https://w.wiki/4Yzf Llista de propietats on apareix un determinat item com a valor
- https://w.wiki/4Zan Valors de Pnnn sense ca label, utilitzat en articles d'asteroide a cawiki
- https://w.wiki/5QTZ Mapa d'inventores per lloc de naixement
- https://w.wiki/5fxN Mapa tombes a cementiri de Montjuïc
- Accés a comptadors contribucions (pdt. estudiar)
- https://w.wiki/5sWp Entitats geogràfiques amb predomini lingüístic = català
Eleccions
[edit]- https://w.wiki/5rmt casos amb un determinat qualif a la P541
- https://w.wiki/5rnF eleccions amb +1 P541
Inventari de qualificadors d'una propietat i llista de casos
[edit]#title:Qualifiers for P1120.
# Canviar P1120 per la propietat a analitzar, als DOS punts del codi
SELECT DISTINCT ?qual ?qualLabel ?count ?llapis
WHERE
{
{
SELECT ?qual (COUNT(DISTINCT ?item) AS ?count) WHERE {
hint:Query hint:optimizer "None" .
?item p:P1120 ?statement .
?statement ?pq_qual ?pq_obj .
?qual wikibase:qualifier ?pq_qual .
} GROUP BY ?qual
} .
BIND (REPLACE(STR(?qual), "http://www.wikidata.org/entity/", "", "i") as ?qualID).
BIND (URI(CONCAT ("https://query.wikidata.org/#SELECT%20%3Fitem%20%3FitemLabel%20%3FtipusLabel%20%3FqualLabel%20%20WHERE%20%7B%0A%20%20%3Fitem%20wdt%3AP31%20%3Ftipus%3B%20p%3A",
"P1120",
"%20%5Bpq%3A",
?qualID,
"%20%3Fqual%5D.%0A%20%20SERVICE%20wikibase%3Alabel%20%7B%20bd%3AserviceParam%20wikibase%3Alanguage%20%22%5BAUTO_LANGUAGE%5D%2Cen%22.%20%7D%0A%7D%0Alimit%20100"
)) as ?llapis)
}
ORDER BY DESC(?count) ASC(?qualLabel)
LIMIT 20
Compta quants statements, referències, enllaços té un item
[edit]#Àrbitres de futbol
SELECT ?item ?itemLabel (COUNT(?props) AS ?count) WHERE {
?item wdt:P106 wd:Q859528.
?item ?props ?link.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel
ORDER BY DESC(?count)
Extreu statements (i les seves referències) i que no hi hagi un altre statement determinat
[edit]# extreure P9984 claims sense P11686. (inclou values per fer proves)
SELECT ?item ?itemLabel ?inspected ?anomenat ?ref ?pr ?rval
WHERE
{
values ?item {
wd:Q750403
wd:Q1200925
}
?item p:P9984 ?statement .
?statement ps:P9984 ?inspected.
OPTIONAL { ?statement pq:P1810 ?anomenat } .
OPTIONAL {
?statement prov:wasDerivedFrom ?ref .
?ref ?pr ?rval .
[] wikibase:reference ?pr
} .
FILTER NOT EXISTS {?item wdt:P11686 ?inspected}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" } .
}
order by asc(?item)
limit 500
Compta quants statements té un tipus d'item
[edit]Versió més reduïda i ràpida de l'anterior. Compta els "claims" de les P31/P279 = eleccions
SELECT ?property ?propertyLabel ?count
WITH
{
SELECT DISTINCT ?item
WHERE
{
?item wdt:P31/wdt:P279* wd:Q40231 .
}
} AS %get_items
WITH
{
SELECT ?property (COUNT(*) as ?count)
WHERE
{
INCLUDE %get_items
?item ?claim [] .
?property wikibase:claim ?claim .
}
GROUP BY ?property
} AS %get_properties
WHERE
{
INCLUDE %get_properties
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" . }
}
ORDER BY DESC(?count)
Obtenir tots els continguts (valors, qualifs i refs) d'una propietat
[edit]#title tots els continguts d'uns items, unes propietats i filtrable per un valor específic
SELECT distinct ?item ?property ?value ?unit ?pq ?qualifier_value ?qualifier_unit ?ref ?pr ?rval
WHERE
{
VALUES ?item { wd:Q515526 } # obligatori, es pot posar una llista
VALUES ?property { wd:P39 } # obligatori, pot ser més d'una propietat
VALUES ?value { wd:Q110546839 } # opcional. Si no s'informa extraurà tots els valors que tingui la property
?property wikibase:claim ?claim .
# Get amount and unit for the statement
?item ?claim ?statement .
{
?property wikibase:propertyType ?property_type .
FILTER (?property_type != wikibase:Quantity)
?property wikibase:statementProperty ?propertyStatement .
?statement ?propertyStatement ?value .
}
UNION
{
?property wikibase:statementValue ?statementValue .
?statement ?statementValue [wikibase:quantityAmount ?value; wikibase:quantityUnit ?unit] .
}
# Get qualifiers
OPTIONAL
{
{
# Get simple values for qualifiers which are not of type quantity
?statement ?propQualifier ?qualifier_value .
?pq wikibase:qualifier ?propQualifier .
?pq wikibase:propertyType ?qualifer_property_type .
FILTER (?qualifer_property_type != wikibase:Quantity)
}
UNION
{
# Get amount and unit for qualifiers of type quantity
?statement ?pqv [wikibase:quantityAmount ?qualifier_value; wikibase:quantityUnit ?qualifier_unit] .
?pq wikibase:qualifierValue ?pqv .
}
}
# get references
OPTIONAL {
?statement prov:wasDerivedFrom ?ref .
?ref ?pr ?rval .
[] wikibase:reference ?pr
}
}
Items amb més d'un P31, un d'ells predeterminat
[edit]# Multiple P31 claims. (inclou FILTER per no igual)
SELECT ?item ?itemLabel ?else ?elseLabel # ?inspected ?itemLabel ?else
WHERE
{
VALUES ?inspected
{
wd:Q476028
}
?item wdt:P31 ?inspected.
?item wdt:P31 ?else FILTER (?else != ?inspected ).
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" } .
}
limit 100
Mostra valors de P31 amb P642, dins un àmbit determinat
[edit]#title: For a topic (now aigua mineral), list the P31 with P642 and their values
SELECT ?item ?itemLabel ?meta ?metaLabel ?criteri ?criteriLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q178921.
?item p:P31 [ps:P31 ?meta; pq:P642 ?criteri]
}
LIMIT 100
Items amb un valor determinat i únic
[edit]SELECT ?item WHERE {
?item wdt:P31 wd:Q486972.
?item wdt:P31 ?value.
}
GROUP BY ?item
HAVING ((COUNT(DISTINCT ?value)) = 1 )
limit 100
Si es vol mostrar el label (o altra informació) cal descriure'ls com OPTIONAL
SELECT ?item ?itemLabel ?itemDescription WHERE {
?item wdt:P31 wd:Q486972, ?value.
OPTIONAL {
?item rdfs:label ?itemLabel.
FILTER((LANG(?itemLabel)) = "ca")
}
OPTIONAL {
?item schema:description ?itemDescription.
FILTER((LANG(?itemDescription)) = "ca")
}
}
GROUP BY ?item ?itemLabel ?itemDescription
HAVING ((COUNT(DISTINCT ?value)) = 1 )
LIMIT 100
Items amb algun dels valors d'una llista (funció OR en valor)
[edit]SELECT ?arxiu_nacional ?arxiu_nacionalLabel ?arxiu ?arxiuLabel ?ubicacio ?ubicacioLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
VALUES ?glam {
wd:Q3052382 # fons documental
wd:Q2668072 # col·lecció
}
?arxiu_nacional wdt:P31 ?glam;
wdt:P126 ?arxiu.
OPTIONAL { ?arxiu_nacional wdt:P276 ?ubicacio. }
}
LIMIT 50
Imatges dels quadres d'un autor en un museu
[edit]#Paintings by "an author" in "a collection"
#defaultView:ImageGrid
SELECT DISTINCT ?item ?itemLabel ?itemDescription ?image ?collection ?collectionLabel ?Inv WHERE {
?item wdt:P31 wd:Q3305213.
?item wdt:P170 ?author.
?item (wdt:P195/wdt:P361*) ?collection.
OPTIONAL { ?item wdt:P18 ?image. }
OPTIONAL { ?item wdt:P217 ?Inv. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]". }
#
#
FILTER(?collection = wd:Q160236) # select museum #
FILTER(?author = wd:Q106851) # select author #
}
Participants en un esport i equip, en un any que figura com a qualificador
[edit]SELECT ?item ?itemLabel ?from ?until ?equip ?equipLabel ?posicio_equipLabel ?alcaria ?massa ?numero_esportiu ?partidos WHERE {
BIND(2017 AS ?year) .
?item wdt:P641 ?esport .
?item p:P54 ?statement .
?statement ps:P54 ?equip; pq:P580 ?from .
OPTIONAL { ?statement pq:P582 ?until } .
OPTIONAL { ?statement pq:P1350 ?partidos } .
FILTER( ?year >= YEAR( ?from ) && !( BOUND( ?until ) && YEAR( ?until ) < ?year ) ) .
FILTER(?esport = wd:Q2736) .
FILTER(?equip = wd:Q7156) .
OPTIONAL { ?item wdt:P413 ?posicio_equip } .
OPTIONAL { ?item wdt:P2048 ?alcaria } .
OPTIONAL { ?item wdt:P2067 ?massa } .
OPTIONAL { ?item wdt:P1618 ?numero_esportiu } .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" } .
}
LIMIT 100
Llista de titulars d'un càrrec específic amb dades del càrrec i de la persona
[edit]SELECT ?item ?itemLabel ?inici ?final ?abans ?abansLabel ?despres ?despresLabel ?partit
?gabinet ?gabinetLabel ?legislatura ?legislaturaLabel ?color__hexadecimal_sRGB_ ?imatge WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item p:P39 ?statement.
?statement ps:P39 ?carrec.
OPTIONAL { ?statement pq:P580 ?inici.}
OPTIONAL { ?statement pq:P582 ?final. }
OPTIONAL { ?statement pq:P1365 ?abans. }
OPTIONAL { ?statement pq:P1366 ?despres. }
OPTIONAL { ?statement pq:P5054 ?gabinet. }
OPTIONAL { ?statement pq:P2937 ?legislatura. }
OPTIONAL { ?item wdt:P18 ?imatge. }
OPTIONAL { ?item wdt:P102 ?partit. }
OPTIONAL { ?partit wdt:P465 ?color__hexadecimal_sRGB_. }
FILTER(?carrec = wd:Q30101464)
}
ORDER BY (?inici)
LIMIT 100
Tots els que tenen algun títol nobiliari (P97) d'una llista, mostrant el càrrec (P39) de la mateixa llista
[edit]# Llista de titulars d'un títol (P97) de comte català + els seus P39-Càrrec
SELECT ?item ?itemLabel ?carrecLabel
?ini ?fi
?ant ?antLabel ?seg ?segLabel
?titolLabel
?ini_T ?fi_T ?ant_T ?ant_TLabel ?seg_T ?seg_TLabel ?imatge
# ?pointInTime ?ordre
WHERE {
VALUES ?carrec {
wd:Q38673587
wd:Q60732050
wd:Q1541699
wd:Q1541813
wd:Q2037817
wd:Q1541642
wd:Q1541642
wd:Q1514510
wd:Q956729
wd:Q657448
wd:Q2338948
wd:Q1541779
wd:Q1541787
wd:Q1297894
}
VALUES ?titol {
wd:Q38673587
wd:Q60732050
wd:Q1541699
wd:Q1541813
wd:Q2037817
wd:Q1541642
wd:Q1541642
wd:Q1514510
wd:Q956729
wd:Q657448
wd:Q2338948
wd:Q1541779
wd:Q1541787
wd:Q1297894
}
?item p:P97 ?p97stm.
?p97stm ps:P97 ?titol.
OPTIONAL { ?p97stm pq:P580 ?ini_T. }
OPTIONAL { ?p97stm pq:P582 ?fi_T. }
OPTIONAL { ?p97stm pq:P1365 ?ant_T. }
OPTIONAL { ?p97stm pq:P1366 ?seg_T. }
OPTIONAL {?item p:P39 ?p39stm.}
?p39stm ps:P39 ?carrec.
# OPTIONAL { ?p39stm pq:P585 ?pointInTime. }
OPTIONAL { ?p39stm pq:P580 ?ini. }
OPTIONAL { ?p39stm pq:P582 ?fi. }
OPTIONAL { ?p39stm pq:P1365 ?ant. }
OPTIONAL { ?p39stm pq:P1366 ?seg. }
# OPTIONAL { ?p39stm pq:P1545 ?ordre. }
OPTIONAL { ?item wdt:P18 ?imatge. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY (?inici)
LIMIT 100
Comptar qualificadors d'una propietat per una llista limitada de'items
[edit]#qualificadors de la P793 per una llista
SELECT ?qual ?qualLabel ?count WHERE {
{
SELECT ?qual (COUNT(DISTINCT ?item) AS ?count) WHERE {
hint:Query hint:optimizer "None" .
VALUES ?item {
wd:Q6534
wd:Q178275
wd:Q20104553
wd:Q131297
wd:Q127912
wd:Q461891
wd:Q3284177
wd:Q29649110
wd:Q36585269
wd:Q36248530
wd:Q27067584
wd:Q23017389
wd:Q16516506
wd:Q57970209
wd:Q959755
wd:Q12650252
wd:Q70990430
wd:Q35785569
wd:Q88177037
wd:Q64038205
wd:Q55475380
}
# Ajustar valor de Pnnn a la propietat a analitzar els qualifs.
?item p:P793 ?statement .
?statement ?pq_qual ?pq_obj .
?qual wikibase:qualifier ?pq_qual .
} GROUP BY ?qual
} .
OPTIONAL {
?qual rdfs:label ?qualLabel filter (lang(?qualLabel) = "ca") .
}
}
ORDER BY DESC(?count) ASC(?qualLabel)
Qualificadors utilitzats per una propietat
[edit]#qualificadors de la P159 per una llista
# Ajustar valor de Pnnn a la propietat a analitzar els qualifs.
SELECT ?qual ?qualLabel ?count WHERE {
{
SELECT ?qual (COUNT(DISTINCT ?item) AS ?count) WHERE {
hint:Query hint:optimizer "None".
?item p:P159 ?statement.
?statement ?pq_qual ?pq_obj.
?qual wikibase:qualifier ?pq_qual.
}
GROUP BY ?qual
}
OPTIONAL {
?qual rdfs:label ?qualLabel.
FILTER((LANG(?qualLabel)) = "ca")
}
}
ORDER BY DESC (?count) (?qualLabel)
LIMIT 20
Valor diferents d'un qualificador indicant en quants items es fa servir
[edit]#diferents valors del qualif P1480 i en quants items/statements es fa servir
SELECT ?P1480value ?P1480valueLabel ?items ?statements
WHERE
{
{
SELECT ?P1480value (COUNT(DISTINCT(?item)) as ?items) (COUNT(?value) as ?statements)
WHERE
{
?prop pq:P1480 ?P1480value .
hint:Query hint:optimizer "None" .
?item ?p ?prop .
?property wikibase:claim ?p .
?property wikibase:statementProperty ?ps .
?prop ?ps ?value .
}
GROUP BY ?P1480value
ORDER BY DESC(?items) DESC(?statements)
LIMIT 100
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "ca,en" }
}
ORDER BY DESC(?items) DESC(?statements)
Seleccionar items per llista i mostrar valors
[edit]#dades comtats catalans
SELECT ?item ?itemLabel ?p31Label ?carrec ?carrecLabel
?estat ?estatLabel ?abans ?abansLabel
?despres ?despresLabel ?creat ?dissolt ?part_de ?part_deLabel
?escut ?mapa ?imatge WHERE {
VALUES ?item {
wd:Q1233672
wd:Q1514510
wd:Q1541699
wd:Q1541813
wd:Q2037817
wd:Q1541642
wd:Q1541642
wd:Q1514510
wd:Q956729
wd:Q657448
wd:Q2338948
wd:Q1541779
wd:Q1541787
wd:Q1297894
wd:Q652275
}
OPTIONAL { ?item wdt:P31 ?p31. }
OPTIONAL { ?item wdt:P1906 ?carrec. }
OPTIONAL { ?item wdt:P17 ?estat. }
OPTIONAL { ?item wdt:P263 ?resid. }
OPTIONAL { ?item wdt:P1365 ?abans. }
OPTIONAL { ?item wdt:P1366 ?despres. }
OPTIONAL { ?item wdt:P18 ?imatge. }
OPTIONAL { ?item wdt:P571 ?creat. }
OPTIONAL { ?item wdt:P576 ?dissolt. }
OPTIONAL { ?item wdt:P361 ?part_de. }
OPTIONAL { ?item wdt:P94 ?escut. }
OPTIONAL { ?item wdt:P242 ?mapa. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Seleccionar item segon el valor d'un qualificador d'un statement
[edit]SELECT ?item ?itemLabel ?coord ?catalogCode ?pointInTime ?describedAtUrl ?notariLabel WHERE {
?item p:P528 ?p528stm .
?p528stm ps:P528 ?catalogCode;
pq:P972 wd:Q20102343.
OPTIONAL { ?p528stm pq:P585 ?pointInTime }
OPTIONAL { ?p528stm pq:P973 ?describedAtUrl }
OPTIONAL { ?p528stm pq:P664 ?notari }
OPTIONAL { ?item wdt:P625 ?coord }
SERVICE wikibase:label { bd:serviceParam wikibase:language 'ca,[AUTO_LANGUAGE]' }
}
Similar anterior, amb selecció AND de varios qualificadors
SELECT ?item ?itemLabel ?coordinates ?catalogCode ?pointInTime ?describedAtUrl WHERE {
?item p:P528 [ ps:P528 ?catalogCode; pq:P972 wd:Q20102343; pq:P585 ?pointInTime; pq:P973 ?describedAtUrl ] .
OPTIONAL { ?item wdt:P625 ?coordinates }
SERVICE wikibase:label { bd:serviceParam wikibase:language 'ca,[AUTO_LANGUAGE]' }
}
Premis atorgats mostrant el valor dels qualificadors que en té
[edit]#Consulta de tots els continguts e P166 per un tipus de premi determinat
SELECT ?item ?itemLabel ?data ?anypremi ?obra ?obraLabel ?afirma ?afirmaLabel
?premi ?premiLabel
WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item p:P166 ?statement.
?statement ps:P166 ?premi.
?premi wdt:P31 ?tipuspremi.
OPTIONAL { ?statement pq:P585 ?data. }
OPTIONAL { ?statement pq:P1686 ?obra. }
OPTIONAL { ?statement pq:P805 ?afirma. }
OPTIONAL { ?statement pq:P1346 ?guanyador. }
FILTER(?tipuspremi = wd:Q19020)
# el filtre pot contenir ?tipuspremi quan es fa servir un genèric (ex.:Oscar)
# o ?premi per indicar un premi específic, com ara "Oscar al millor ...."
}
ORDER BY (?data)
LIMIT 6000
Seleccionar item amb dos qualificadors simultàniament en una propietat determinada
[edit]# Llista d'articles amb una propietat (p:Pnnnn)
# que tingui simultàniament dos qualificadors específics
SELECT ?item ?itemLabel ?tipusLabel ?qualLabel ?qual2Label WHERE {
?item wdt:P31 ?tipus;
p:P1346 [
pq:P1351 ?qual;
pq:P1013 ?qual2
].
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
limit 100
Mostrar combinadament propietats i qualificadors, sense que formin part del filtre. Només articles en català
[edit]# Mostrar combinadament propietats i qualificadors, sense que formin part del filtre
SELECT DISTINCT ?item ?itemLabel ?participant ?participantLabel ?data_d_inici ?gestor ?gestorLabel ?representantLabel ?delimitat_per ?delimitat_perLabel ?mapa_localitzador WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q15221623.
OPTIONAL { ?item wdt:P710 ?participant. }
OPTIONAL { ?item wdt:P580 ?data_d_inici. }
OPTIONAL { ?item wdt:P4777 ?delimitat_per. }
OPTIONAL { ?item wdt:P242 ?mapa_localitzador. }
OPTIONAL {
?item p:P710 ?p710stm.
?p710stm ps:P710 ?catalogCode;
pq:P137 ?gestor;
pq:P1875 ?representant.
}
?sitelink schema:about ?item;
schema:inLanguage "ca".
}
LIMIT 100
Selecciona items amb un qualificador específic en una propietat específica i mostra el seu valor
[edit]SELECT ?item ?itemLabel ?tipusLabel ?qualLabel WHERE {
?item wdt:P31 ?tipus;
p:P1435 [
pq:P2614 ?qual
].
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
limit 1000
Total de usos d'una propietat, mostrant a més altres propietats de cadascun dels valors totalitzats
[edit]#Total de usos d'una propietat, mostrant a més altres propietats de cadascun dels valors totalitzats
SELECT ?value ?valueLabel ?ct ?sampleitem ?sampleitemLabel ?propassoc
WHERE
{
{
SELECT ?value (count(*) as ?ct) (SAMPLE(?item) as ?sampleitem)
WHERE
{
?item wdt:P1435 ?value.
}
GROUP BY ?value
ORDER BY DESC(?ct)
LIMIT 1000
}
#mostrar la P1687 de cadascun dels valors totalitzats
?value wdt:P1687 ?propassoc.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY DESC(?ct) ASC(?value)
Items d'una subclasse que tenen NO tenen una propietat (P18=sense imatge). Només articles en català
[edit]# "escut de..." sense P18
PREFIX schema: <http://schema.org/>
SELECT ?item ?itemLabel ?imatge ?itjuris ?itjurisLabel ?jurisdicci_ ?jurisdicci_Label WHERE {
?item (wdt:P31/wdt:P279*) wd:Q14659.
minus { ?item wdt:P18 ?imatge. }
?sitelink schema:about ?item.
?sitelink schema:inLanguage "ca".
SERVICE wikibase:label { bd:serviceParam wikibase:language "ca,en". }
}
LIMIT 10
Items d'una subclasse que tenen una propietat (P1001), la qual apunta a un item que NO té una certa propietat (P237)
[edit]# "escut de..." amb P1001-jurisdicció, que no tingui P237 de retorn a un "escut de.."
PREFIX schema: <http://schema.org/>
SELECT ?item ?itemLabel ?itjuris ?itjurisLabel ?jurisdicci_ ?jurisdicci_Label WHERE {
?item (wdt:P31/wdt:P279*) wd:Q14659.
?item wdt:P1001 ?jurisdicci_.
?sitelink schema:about ?item.
?sitelink schema:inLanguage "ca".
SERVICE wikibase:label { bd:serviceParam wikibase:language "ca,en". }
minus { ?itjuris wdt:P237 ?item.}
}
LIMIT 100
Llista d'items amb coordenades mostrant la precisió de les coordenades
[edit]#BCIN amb precisió
SELECT DISTINCT ?lloc ?llocLabel ?lat ?lon ?coord ?prec
WHERE {
?lloc wdt:P1435 wd:Q1019352.
?lloc p:P625 ?coordinate .
?lloc wdt:P625 ?coord.
?coordinate psv:P625 ?coordinate_node .
?coordinate_node wikibase:geoLatitude ?lat .
?coordinate_node wikibase:geoLongitude ?lon .
?coordinate_node wikibase:geoPrecision ?prec.
SERVICE wikibase:label {
bd:serviceParam wikibase:language 'ca' . }
}
ORDER BY DESC(?prec)
Mapa amb la localització de patrimoni catalogat en un municipi
[edit]#defaultView:Map
SELECT ?item ?itemLabel ?coordenades ?estatus_patrimonial ?estatus_patrimonialLabel WHERE {
?item wdt:P1435 wd:Q65553409;
wdt:P131 wd:Q497801;
wdt:P625 ?coordenades.
OPTIONAL { ?item wdt:P1435 ?estatus_patrimonial. }
Mapa amb la localització d'esglésies a una comarca determinada
[edit]#defaultView:Map
SELECT ?item ?itemLabel ?coordenades ?municipi ?municipiLabel ?imatge WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item (wdt:P31/(wdt:P279*)) wd:Q16970;
wdt:P131 ?municipi.
?municipi wdt:P131 ?comarca.
OPTIONAL { ?item wdt:P625 ?coordenades. }
OPTIONAL { ?item wdt:P18 ?imatge. }
FILTER(?comarca = wd:Q12793) # select comarca (or second level of P131) #
}
LIMIT 400
Distribució escons d'una legislatura per partit
[edit]#defaultView:bubble
# Distribució escons d'una legislatura per partit
SELECT ?item ?sigles ?logo ?escons ?itemLabel ?parlamentLabel WHERE {
?item p:P1410 ?p528stm .
?p528stm ps:P1410 ?escons;
pq:P2937 wd:Q47034616.
OPTIONAL { ?p528stm pq:P194 ?parlament }
OPTIONAL { ?item wdt:P154 ?logo }
OPTIONAL { ?item wdt:P1813 ?sigles }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en"}
}
Select items where a property starts by xx
[edit]Hi, I need all the municipality of Catalonia (Q33146843) where its IDESCAT territorial code in Catalonia (P4335) has 43 in the two first digits of the code. Thanks, Amadalvarez (talk) 05:29, 16 August 2019 (UTC)
- @Amadalvarez:
- Try it!
SELECT ?item ?itemLabel (?p4335 AS ?IDESCAT_code) { ?item wdt:P31 wd:Q33146843 . ?item wdt:P4335 ?p4335 . FILTER(STRSTARTS(?p4335,'43')) SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } } ORDER BY ?p4335
Obtenir el qualificador del valor de la propietat amb rank preferred
[edit]SELECT DISTINCT ?item ?itemLabel ?poblacio ?superficie ?imatge_de_l_escut_d_armes ?pointInTime WHERE {
?item wdt:P31 wd:Q33146843;
wdt:P4335 ?p4335.
FILTER(STRSTARTS(?p4335, "25"))
OPTIONAL { ?item p:P1082 [ps:P1082 ?poblacio; pq:P585 ?pointInTime; wikibase:rank wikibase:PreferredRank] . }
OPTIONAL { ?item wdt:P2046 ?superficie. }
OPTIONAL { ?item wdt:P94 ?imatge_de_l_escut_d_armes. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 100
Llista premis Oscar d'un any concret
[edit]SELECT ?item ?itemLabel ?premia ?premi ?premiLabel ?data ?obra ?obraLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P166 ?premia.
?premia wdt:P31 wd:Q19020.
OPTIONAL { ?item p:P166 [ps:P166 ?premi; pq:P585 ?data; pq:P1686 ?obra] . }
filter (?premi = ?premia) #filtra instàncies d'altres premis del mateix any
filter (?data >= "2019-01-01T00:00:00Z"^^xsd:dateTime && ?data < "2020-01-01T00:00:00Z"^^xsd:dateTime)
}
LIMIT 100
Llista d'items redireccionats
[edit]# Llista items redireccionats
#
SELECT ?redirect ?item WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?redirect owl:sameAs ?item
}
LIMIT 1000
Verifica que Qids incloses dins el codi no s'hagin redireccionat
[edit]# Llista items redireccionats
#
SELECT ?redirect ?item WHERE {
VALUES ?redirect {
# Control Qid incloses al # Switch de Plantilla:Global_infobox_person/sports
wd:Q89615333 #Amèrica del Sud, redirigida
wd:Q2736 # football
wd:Q8418 # handbol
wd:Q171401 # futbol sala
wd:Q185851 # lacrosse
wd:Q7707 # waterpolo
wd:Q134211 # polo
wd:Q1455 # hoquei herba
wd:Q1748406 # hoquei patins
wd:Q946171 # hoquei patins en línia
wd:Q41466 # hoquei gel
wd:Q5372 # basquet
wd:Q5369 # beisbol
wd:Q3930 # tennis taula
wd:Q171038 # softbol
wd:Q1734 # voleibol
wd:Q5378 # rugbi
wd:Q10962 # rugbi 13
wd:Q41323 # football americà
wd:Q50776 # football australià
wd:Q5849 # rugbi 15
wd:Q5375 # criquet
wd:Q608003 # motociclisme
wd:Q328716 # motociclisme
wd:Q850292 # motociclisme de velocitat
wd:Q5386 # automobilisme
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?redirect owl:sameAs ?item.
}
LIMIT 100
Llista de Catalans vius nascuts entre 1898 i 1918
[edit]#Catalans vius nascuts entre 1898 i 1918
SELECT ?s ?desc
WHERE
{
?s wdt:P31 wd:Q5 ;
wdt:P569 ?naix .
?s wdt:P19 ?lloc .
?lloc wdt:P131*/wdt:P706* wd:Q5705.
FILTER (?naix > "1898-01-01"^^xsd:dateTime && ?naix < "1918-01-01"^^xsd:dateTime)
MINUS { ?s wdt:P570 [] }
?s rdfs:label ?desc FILTER(lang(?desc)="ca").
SERVICE wikibase:label { bd:serviceParam wikibase:language "ca". }
?article schema:about ?s .
?article schema:inLanguage "ca" .
?article schema:isPartOf <https://ca.wikipedia.org/>
}
GROUP BY ?s ?desc
LIMIT 100
Valors fora de llista de manner of death (P1196)
[edit]SELECT ?item ?circumst_ncies_de_la_mort ?circumst_ncies_de_la_mortLabel ?causa_de_mort ?causa_de_mortLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q5;
wdt:P1196 ?circumst_ncies_de_la_mort;
wdt:P509 ?causa_de_mort.
minus { ?item wdt:P1196 wd:Q10737. }
minus { ?item wdt:P1196 wd:Q171558. }
minus { ?item wdt:P1196 wd:Q3739104. }
minus { ?item wdt:P1196 wd:Q149086. }
minus { ?item wdt:P1196 wd:Q8454. }
minus { ?item wdt:P1196 wd:Q18663901. }
minus { ?item wdt:P1196 wd:Q855919. }
}
LIMIT 2000
Mapa dels museus amb pintures a Espanya
[edit]#defaultView:Map
SELECT ?item ?itemLabel ?collectionLabel ?geoloc ?image WHERE {
?item wdt:P31 wd:Q3305213.
?item wdt:P195 ?collection.
?collection wdt:P625 ?geoloc.
?collection wdt:P17 wd:Q29.
SERVICE wikibase:label { bd:serviceParam wikibase:language "ca,es,en". }
OPTIONAL { ?item wdt:P18 ?image. }
}
LIMIT 5000
Llista el valor de diversos labels
[edit]SELECT ?item ?itemLabel ?itemLabel_ga ?instancia_de ?instancia_deLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "ca". }
?item (wdt:P131*) wd:Q25;
rdfs:label ?itemLabel_ga.
FILTER((LANG(?itemLabel_ga)) = "ga")
OPTIONAL { ?item wdt:P31 ?instancia_de. }
}
LIMIT 5000
Agafar "forma femenina del label"
[edit]#female form of label
SELECT ?item ?itemLabel ?gender ?genderLabel ?profession ?professionText WHERE {
?item wdt:P106 wd:Q1028181;
wdt:P135 wd:Q34636;
wdt:P21 wd:Q6581072.
OPTIONAL { ?item wdt:P21 ?gender. }
OPTIONAL { ?item wdt:P18 ?image. }
OPTIONAL { ?item wdt:P19 ?place. }
OPTIONAL { ?item wdt:P569 ?date. }
OPTIONAL {
?item wdt:P106 ?profession.
OPTIONAL {
?profession wdt:P2521 ?female_form_of_label.
FILTER((LANG(?female_form_of_label)) = "ca")
}
OPTIONAL {
?profession rdfs:label ?professionLabel.
FILTER((LANG(?professionLabel)) = "ca")
}
}
BIND(IF((?gender IN(wd:Q6581072, wd:Q1052281, wd:Q43445)) && (BOUND(?female_form_of_label)), ?female_form_of_label, ?professionLabel) AS ?professionText)
SERVICE wikibase:label { bd:serviceParam wikibase:language "ca,[AUTO_LANGUAGE]". }
}
editar data DMD segons precisió
[edit]SELECT ?item ?dob ?dob_precision ?dob_edited
WHERE
{
?item wdt:P31 wd:Q5 . # Humans
?item wdt:P19 wd:Q1492 . # born in Barcelona
?item p:P569 ?dob_statement .
?dob_statement a wikibase:BestRank .
?dob_statement psv:P569 ?dob_value .
?dob_value wikibase:timeValue ?dob .
?dob_value wikibase:timePrecision ?dob_precision .
BIND (COALESCE(
IF(?dob_precision = 11, CONCAT(STR(DAY(?dob)), "-", STR(MONTH(?dob)), "-", STR(YEAR(?dob))), 1/0),
IF(?dob_precision = 10, CONCAT(STR(MONTH(?dob)), "-", STR(YEAR(?dob))), 1/0),
IF(?dob_precision = 9, STR(YEAR(?dob)), 1/0),
IF(?dob_precision = 8, CONCAT(STR(FLOOR(YEAR(?dob)/10)*10), "s"), 1/0),
IF(?dob_precision = 7, CONCAT(STR(FLOOR((YEAR(?dob)+99)/100)), " century"), 1/0),
IF(?dob_precision = 6, CONCAT(STR(FLOOR((YEAR(?dob)+999)/1000)), " milleium"), 1/0),
"Unhandled precision"
) AS ?dob_edited)
}
Limit 5000
Seleccionar per unitat d'una propietat numèrica
[edit]#title: Seleccionar per la unitat (m., km,.) d'una propietat numèrica (amplada, llargada,superficie,..)
SELECT ?object ?objectLabel ?baselong ?instancia ?instanciaLabel WHERE {
?object (p:P2043/psv:P2043) _:b5.
_:b5 wikibase:quantityAmount ?baselong;
wikibase:quantityUnit wd:Q828224.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?object wdt:P31 ?instancia. # informa P31 per saber si és una unitat coherent amb l'element
}
LIMIT 500
Comptar per valor i unitat d'una propietat numèrica
[edit]#Values used by property P3279
SELECT ?value ?unity ?unityLabel ?ct ?sampleitem ?sampleitemLabel
WHERE
{
{
SELECT ?value ?unity (count(*) as ?ct) (SAMPLE(?item) as ?sampleitem)
WHERE
{
?item wdt:P31/wdt:P279* wd:Q16510064.
?item (p:P2257/psv:P2257) _:b5.
_:b5 wikibase:quantityAmount ?value;
wikibase:quantityUnit ?unity.
}
GROUP BY ?value ?unity
ORDER BY DESC(?ct)
LIMIT 1000
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY DESC(?ct) ASC(?value)
Selecció amb UNION. Capital de comarca o població amb > 25.000 habitants
[edit]#vots en capitals de comarca o > 25.000 habitants
SELECT DISTINCT ?municipiLabel ?capital_deLabel ?poblacio ?emesos ?vots_PP
?vots_JUNTS ?vots_PSC ?vots_Cs ?vots_ERC
?vots_Comuns ?vots_VOX ?vots_CUP WHERE {
?item wdt:P361 wd:Q48838589;
wdt:P1001 ?municipi.
{
?municipi wdt:P1376 ?capital_de .
?capital_de wdt:P31 wd:Q937876
}
UNION
{
?item wdt:P361 wd:Q48838589;
wdt:P1001 ?municipi.
?municipi wdt:P1082 ?poblacio.
FILTER(?poblacio >= 25000) .
}
OPTIONAL { ?item wdt:P1868 ?emesos. }
OPTIONAL { ?item p:P726?statement.
?statement ps:P726 wd:Q185088;
pq:P1111 ?vots_PP.}
OPTIONAL { ?item p:P726 ?statement1.
?statement1 ps:P726 wd:Q97155800;
pq:P1111 ?vots_JUNTS.}
OPTIONAL { ?item p:P726 ?statement2.
?statement2 ps:P726 wd:Q2055003;
pq:P1111 ?vots_PSC. }
OPTIONAL { ?item p:P726?statement3.
?statement3 ps:P726 wd:Q1393123;
pq:P1111 ?vots_Cs.}
OPTIONAL { ?item p:P726?statement4.
?statement4 ps:P726 wd:Q150068;
pq:P1111 ?vots_ERC.}
OPTIONAL { ?item p:P726?statement5.
?statement5 ps:P726 wd:Q104760756;
pq:P1111 ?vots_Comuns.}
OPTIONAL { ?item p:P726?statement6.
?statement6 ps:P726 wd:Q15630787;
pq:P1111 ?vots_VOX.}
OPTIONAL { ?item p:P726?statement7.
?statement7 ps:P726 wd:Q104760691;
pq:P1111 ?vots_CUP.}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Llistat amb wikidata list generant les coordenades
[edit]SELECT ?item ?itemLabel ?municipiLabel ?construcció ?estatLabel ?imatge ?geoportail
WHERE {
?item wdt:P361 wd:Q27882848.
SERVICE wikibase:label { bd:serviceParam wikibase:language "ca,es,en". }
OPTIONAL { ?item wdt:P131 ?municipi. }
OPTIONAL { ?item wdt:P571 ?construcció. }
OPTIONAL { ?item wdt:P5816 ?estat. }
OPTIONAL { ?item wdt:P18 ?imatge. }
OPTIONAL { ?item p:P625 [ psv:P625 [ wikibase:geoLatitude ?latitude; wikibase:geoLongitude ?longitude ] ].}
BIND ((STR(?latitude)) as ?lat) . BIND ((STR(?longitude)) as ?lon) .
BIND(CONCAT("[", "https://geohack.toolforge.org/geohack.php?pagename=Llista_d%27unitats_de_la_Xarxa_Nacional_de_Sitges_i_Graners&language=ca¶ms=", ?lat, "_N_", ?lon, "_E coord:", ?lat, ",", ?lon, "]") AS ?geoportail)
}
Creuar dos conceptes segons el seu valor: símbol químic i codi de llengua. Requereix doble select encadenada
[edit]Powered by Quelet.
#Símbols químics que coincideixen amb un codi ISO 639-1 de llengua
SELECT ?aaa ?llenguaLabel WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
{
SELECT ?ele ?nat ?sim ?eleLabel ?llenguaLabel ?aaa WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
?ele wdt:P31 wd:Q11344.
?ele wdt:P246 ?sim.
?ele wdt:P1086 ?nat. }
}
?llengua wdt:P31 wd:Q1288568.
BIND (LCASE(str(?sim)) AS ?aaa)
?llengua wdt:P218 ?aaa . }
Persones amb més premis. Comptar multivalors, doble select, labels només dels seleccionats
[edit]LIMIT 40
i FILTER ... >25
són alternatius.
Amb LIMIT mostrarà el 40 més alts i amb FILTER mostrarà tots els que tinguin més de nn
#nombre de premis
SELECT distinct ?item ?itemLabel ?count
{ { SELECT ?item (COUNT(?props) AS ?count)
{ ?item wdt:P166 ?props. }
GROUP BY ?item
ORDER BY DESC (?count)
# LIMIT 40
}
?sitelink schema:about ?item;
schema:inLanguage "ca".
FILTER( ?count > 25) .
OPTIONAL {?item rdfs:label ?itemLabel. FILTER((LANG(?itemLabel)) = "ca")}
}
Comptar items amb diverses combinacions de propietats
[edit]#title: Mix of P159, P115 & P276 used in sport event
SELECT ?value ?ct ?sampleitem ?sampleitemLabel
WHERE
{
{
SELECT ?value (count(*) as ?ct) (SAMPLE(?item) as ?sampleitem)
WHERE
{
?item (wdt:P31/(wdt:P279*)) wd:Q16510064. # àmbit sobre el que es vol explorar
optional { ?item wdt:P159 ?p159.} # propietats a analitzar si hi són
optional { ?item wdt:P115 ?p115.}
optional { ?item wdt:P276 ?p276.}
BIND(IF(BOUND(?p159),"P159","") AS ?seu). # genera text per cada propietat existent
BIND(IF(BOUND(?p115),"P115","") AS ?sta).
BIND(IF(BOUND(?p276),"P276","") AS ?loc).
bind(CONCAT(?seu, "-", ?sta, "-", ?loc) as ?value). #crear un codi amb els textos concatenats
}
GROUP BY ?value
ORDER BY DESC(?ct)
LIMIT 10 }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" }
}
ORDER BY DESC(?ct) ASC(?value)
Construcció contingut per Listeriabot evitant posar row_template
[edit]# generació continguts preparats per Listeriabot i evitar row_template
SELECT distinct * WHERE {
VALUES ?tipus {wd:Q489357 wd:Q585956}
?item wdt:P17 wd:Q29; rdfs:label ?itemLabel. FILTER(LANG(?itemLabel) = "ca").
?item wdt:P31/wdt:P279* ?tipus.
?item wdt:P131* ?municipi.
?municipi wdt:P31 wd:Q33146843; rdfs:label ?municipiLabel. FILTER(LANG(?municipiLabel) = "ca").
?municipi wdt:P131 wd:Q14303.
OPTIONAL {?item wdt:P18 ?imatgebrut. }
BIND(IF(BOUND(?imatgebrut),
REPLACE(STR(?imatgebrut), "http://commons.wikimedia.org/wiki/Special:FilePath/", "", "i"), " ")
as ?imatgenom).
BIND(IF(BOUND(?imatgebrut),
CONCAT("[","[","File:", ?imatgenom, "|60px","]","]" ), " ")
as ?imatge).
OPTIONAL {?item wdt:P2044 ?alt. }
BIND(IF(BOUND(?alt),CONCAT (" (", STR(?alt), "↑)"),"") AS ?altitude).
OPTIONAL {?item p:P625 [ psv:P625 [ wikibase:geoLatitude ?latitude; wikibase:geoLongitude ?longitude ] ].}
BIND (REPLACE(STR(?item), "http://www.wikidata.org/entity/", "", "i") as ?itemId).
BIND (CONCAT ("[","[","File:Arbcom ru editing.svg|12px|center|",
"Modifica les dades a Wikidata|", ?lat, "|", ?lon,
"|dim:100", "|", ?lat, "|", ?lon,
"|dim:100", "
Items sense etiqueta ca utilitzats en algun article
[edit]Actualment mira professions.
#sense label ca i amb articles que el fan servir
SELECT DISTINCT ?ocupa ?ocupaLabel
WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE]", "en". }
?item wdt:P106 ?ocupa.
?sitelink schema:about ?item;
schema:inLanguage "ca".
FILTER NOT EXISTS {?ocupa rdfs:label ?ocupaLabelCA filter (lang(?ocupaLabelCA) = "ca")}
}
LIMIT 100
#title: Items sense etiqueta en català
SELECT distinct ?item ?itemLabel_en ?itemDescription_en ?itemLabel_ca ?itemDescription_ca
WHERE {
?item (wdt:P31/wdt:P279*) wd:Q15328; rdfs:label ?itemLabel_en. #FILTRA PER items subclasse de càmera
FILTER((LANG(?itemLabel_en)) = "en") #recupera etiqueta "en"
FILTER(NOT EXISTS {?item rdfs:label ?itemLabel_ca. #elimina si té etiqueta "ca"
FILTER((LANG(?itemLabel_ca)) = "ca")
})
OPTIONAL { ?item wdt:P31 ?instancia_de. ?instancia_de rdfs:label ?instancia_deLabel.
FILTER((LANG(?instancia_deLabel)) = "en")} #mostra P31 en "en"
OPTIONAL {
?item schema:description ?itemDescription_en.
FILTER((LANG(?itemDescription_en)) = "en")
}
OPTIONAL {
?item schema:description ?itemDescription_ca.
FILTER((LANG(?itemDescription_ca)) = "ca")
LIMIT 500
}}
Items sense "forma femenina de l'etiqueta" ca
[edit]#sense female form of label en ca. Canviar P31= càrrecs, professions, etc.
SELECT ?item ?itemLabel ?female_form_of_label WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item wdt:P31 wd:Q28640.
MINUS {
?item wdt:P2521 ?female_form_of_label.
FILTER((LANG(?female_form_of_label)) = "ca")
}
}
Comparar P276 amb altres propietats amb un OR
[edit]# P276-localització i altres continguts
SELECT distinct ?item ?itemLabel ?dupli ?lloc ?llocLabel ?p131 ?p131Label
?p361 ?p361Label ?p706 WHERE {
VALUES ?item {
wd:Q12431
wd:Q23145
wd:Q131135
}
?item wdt:P276 ?lloc.
OPTIONAL { ?item wdt:P361 ?p361. }
OPTIONAL { ?item wdt:P131 ?p131. }
OPTIONAL { ?item wdt:P706 ?p706. }
BIND(IF((?lloc IN(?p361, ?p131, ?p706)), "dup", "") AS ?dupli)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Eleccions amb P580, mostrant P582 i P585. Edita dates segons precisió
[edit]#Classe ELECCIONS amb P580, mostrant P582 i P585
SELECT distinct ?eleccions ?eleccionsLabel ?igual_1
?p585_edited ?p585pr
?p580_edited ?p580pr
?p582_edited ?p582pr ?igual_2
WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?eleccions (wdt:P31/(wdt:P279*)) wd:Q18669875;
wdt:P580 ?data_d_inici.
OPTIONAL { ?eleccions p:P585 ?p585_statement .
?p585_statement psv:P585 ?p585_value .
?p585_value wikibase:timeValue ?p585 .
?p585_value wikibase:timePrecision ?p585_precision .
BIND (COALESCE(
IF(?p585_precision = 11, CONCAT(STR(DAY(?p585)), "-", STR(MONTH(?p585)), "-", STR(YEAR(?p585))), 1/0),
IF(?p585_precision = 10, CONCAT(STR(MONTH(?p585)), "-", STR(YEAR(?p585))), 1/0),
IF(?p585_precision = 9, STR(YEAR(?p585)), 1/0),
IF(?p585_precision = 8, CONCAT(STR(FLOOR(YEAR(?p585)/10)*10), "s"), 1/0),
IF(?p585_precision = 7, CONCAT(STR(FLOOR((YEAR(?p585)+99)/100)), " century"), 1/0),
IF(?p585_precision = 6, CONCAT(STR(FLOOR((YEAR(?p585)+999)/1000)), " milleium"), 1/0),
"Unhandled precision"
) AS ?p585_edited)
BIND (
IF(?p585_precision = 11,
"","prec"
) AS ?p585pr)
}
OPTIONAL { ?eleccions p:P582 ?p582_statement .
?p582_statement psv:P582 ?p582_value .
?p582_value wikibase:timeValue ?p582 .
?p582_value wikibase:timePrecision ?p582_precision .
BIND (COALESCE(
IF(?p582_precision = 11, CONCAT(STR(DAY(?p582)), "-", STR(MONTH(?p582)), "-", STR(YEAR(?p582))), 1/0),
IF(?p582_precision = 10, CONCAT(STR(MONTH(?p582)), "-", STR(YEAR(?p582))), 1/0),
IF(?p582_precision = 9, STR(YEAR(?p582)), 1/0),
IF(?p582_precision = 8, CONCAT(STR(FLOOR(YEAR(?p582)/10)*10), "s"), 1/0),
IF(?p582_precision = 7, CONCAT(STR(FLOOR((YEAR(?p582)+99)/100)), " century"), 1/0),
IF(?p582_precision = 6, CONCAT(STR(FLOOR((YEAR(?p582)+999)/1000)), " milleium"), 1/0),
"Unhandled precision"
) AS ?p582_edited)
BIND (
IF(?p582_precision = 11,
"","prec"
) AS ?p582pr)
}
?eleccions p:P580 ?p580_statement .
?p580_statement psv:P580 ?p580_value .
?p580_value wikibase:timeValue ?p580 .
?p580_value wikibase:timePrecision ?p580_precision .
BIND (COALESCE(
IF(?p580_precision = 11, CONCAT(STR(DAY(?p580)), "-", STR(MONTH(?p580)), "-", STR(YEAR(?p580))), 1/0),
IF(?p580_precision = 10, CONCAT(STR(MONTH(?p580)), "-", STR(YEAR(?p580))), 1/0),
IF(?p580_precision = 9, STR(YEAR(?p580)), 1/0),
IF(?p580_precision = 8, CONCAT(STR(FLOOR(YEAR(?p580)/10)*10), "s"), 1/0),
IF(?p580_precision = 7, CONCAT(STR(FLOOR((YEAR(?p580)+99)/100)), " century"), 1/0),
IF(?p580_precision = 6, CONCAT(STR(FLOOR((YEAR(?p580)+999)/1000)), " milleium"), 1/0),
"Unhandled precision"
) AS ?p580_edited)
BIND (
IF(?p580_precision = 11,
"","prec"
) AS ?p580pr)
BIND (
IF(?p580_edited = ?p585_edited, "data=inici",
IF(?p582_edited = ?p585_edited, "data=final",""
)) AS ?igual_1)
BIND (
IF(?p580_edited = ?p582_edited,
"inici=final",""
) AS ?igual_2)
}
LIMIT 900
Totes les propietats que fan servir un conjunt d'items
[edit]#title Totes les propietats utilitzades per un conjunt d'items (càmeres)
SELECT ?property ?propertyLabel ?count
WITH
{
SELECT DISTINCT ?item
WHERE
{
?item wdt:P31/wdt:P279* wd:Q15328 .
}
} AS %get_items
WITH
{
SELECT ?property (COUNT(*) as ?count)
WHERE
{
INCLUDE %get_items
?item ?claim [] .
?property wikibase:claim ?claim .
}
GROUP BY ?property
} AS %get_properties
WHERE
{
INCLUDE %get_properties
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en" . }
}
ORDER BY DESC(?count)
Selecciona amb un OR de propietats
[edit]SELECT ?item ?total ?nit ?hivern ?aire ?entra ?int
# ?vista_nocturna ?vista_hivernal ?vista_a_ria ?imatge_entrada ?imatge_interior
WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
VALUES ?img {
wd:Q41176
wd:Q16970
wd:Q23413
wd:Q4989906
wd:Q131681
}
?item wdt:P31 ?img.
OPTIONAL { ?item wdt:P3451 ?vista_nocturna. }
OPTIONAL { ?item wdt:P5252 ?vista_hivernal. }
OPTIONAL { ?item wdt:P8592 ?vista_a_ria. }
OPTIONAL { ?item wdt:P9721 ?imatge_entrada. }
OPTIONAL { ?item wdt:P5775 ?imatge_interior. }
BIND(IF(BOUND(?vista_nocturna),1,0) AS ?nit).
BIND(IF(BOUND(?vista_hivernal),1,0) AS ?hivern).
BIND(IF(BOUND(?vista_a_ria),1,0) AS ?aire).
BIND(IF(BOUND(?imatge_entrada),1,0) AS ?entra).
BIND(IF(BOUND(?imatge_interior),1,0) AS ?int).
BIND (STR(?nit + ?hivern + ?aire + ?entra + ?int) as ?total)
FILTER( ?total != "0" )
}
LIMIT 10000
items eleccions amb P1539-població femenina als resultats
[edit]- als partits
#title: items eleccions amb P1539-població femenina als resultats dels partits
SELECT ?item ?itemLabel ?població_femenina
WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item (wdt:P31/(wdt:P279*)) wd:Q40231.
?item p:P991 [ps:P991 ?meta; pq:P1539 ?població_femenina]
}
LIMIT 4000
- als resultats de l'elecció
#title: items eleccions amb P1539-població femenina als resultats dels partits
SELECT ?item ?itemLabel ?població_femenina
WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?item (wdt:P31/(wdt:P279*)) wd:Q40231.
?item p:P1867 [ps:P1867 ?meta; pq:P1539 ?població_femenina]}
LIMIT 1000
Llista dades tècniques d'objectius agrupant els multi-valors (GROUP_CONCAT)
[edit]- als partits
#title: dades tècniques objectius (amb focal i obertura)
SELECT DISTINCT ?item ?itemLabel ?muntura ?munturaLabel ?elements ?grups ?fulles (GROUP_CONCAT(DISTINCT ?distància_focal; separator=", ") AS ?focals )
(GROUP_CONCAT(DISTINCT ?obertura; separator=", ") AS ?obertures ) ?enfocament ?diametre_o ?diametre_f
?estabilitzador ?estabilitzadorLabel ?lloc ?llocLabel ?web WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en".
?item rdfs:label ?itemLabel .
?muntura rdfs:label ?munturaLabel .
?estabilitzador rdfs:label ?estabilitzadorLabel.
?lloc rdfs:label ?llocLabel .
}
?item (wdt:P279*) wd:Q192234.
OPTIONAL {
?item p:P2935 _:b6.
_:b6 ps:P2935 ?muntura;
pq:P518 wd:Q205722.
}
OPTIONAL {
?item p:P2283 _:b7.
_:b7 ps:P2283 wd:Q115743910;
pq:P1114 ?elements.
}
OPTIONAL {
?item p:P2283 _:b8.
_:b8 ps:P2283 wd:Q115744033;
pq:P1114 ?grups.
}
OPTIONAL {
?item p:P2283 _:b9.
_:b9 ps:P2283 wd:Q115745185;
pq:P1114 ?fulles.
}
OPTIONAL { ?item wdt:P11412 ?enfocament. }
OPTIONAL {
?item p:P2386 _:b10.
_:b10 ps:P2386 ?diametre_f;
pq:P518 wd:Q876650.
}
OPTIONAL {
?item p:P2386 _:b11.
_:b11 ps:P2386 ?diametre_o;
pq:P518 wd:Q192234.
}
OPTIONAL { ?item wdt:P11415 ?estabilitzador. }
OPTIONAL { ?item wdt:P1071 ?lloc. }
OPTIONAL { ?item wdt:P856 ?web. }
OPTIONAL { ?item wdt:P2151 ?distància_focal. }
OPTIONAL { ?item wdt:P7863 ?obertura. }
}
GROUP BY ?item ?itemLabel ?muntura ?munturaLabel ?elements ?grups ?fulles ?enfocament ?diametre_o ?diametre_f
?estabilitzador ?estabilitzadorLabel ?lloc ?llocLabel ?web
LIMIT 4000